Ejercicios con PseInt de estructuras repetitivas - Intermedio

EJERCICIO #1

---

Crear una calculadora en pseudocódigo, que permita ingresar un número positivo y lo devuelva en binario.

Proceso base10a2
   //Variables de entrada
   Definir a Como Entero 
   //Variable auxiliar
   Definir aux Como Entero
   //Variable de salida
   Definir bin Como Entero
   //Inicializar contador
   aux<-1
   //Inicializar acumulador
   bin<-0
   //CAPTURA DE DATOS
   Repetir
     Escribir "Ingrese un número positivo"
     Leer a
   Hasta Que a > 0
   //PROCESO y SALIDA 
   Escribir a Sin Saltar
   Mientras a>=2 Hacer
     bin<-bin+(a%2)*aux
     aux<-aux*10
     a<-(a-a%2)/2
   FinMientras 
   bin<-bin + a * aux
   Escribir " en binario es: ", bin
FinProceso

EJERCICIO #2

---

Realizar un pseudocódigo que permita calcular el factorial de un número entero positivo. Nota: Mostrar 1 si se pide calcular el factorial de cero.

Proceso factorial
 //Variables de entrada
 Definir num,fact Como Entero 
 //Inicializar acumulador
 fact<-1
 //CAPTURA DE DATOS
 Repetir
  Escribir "Ingrese el primer número"
  Leer num
 Hasta Que num >= 0 
 //PROCESO
 Para i<-1 Hasta num Con Paso 1 Hacer
  fact<-fact*i
 FinPara 
 //SALIDA
 Escribir num,"! = ", fact
FinProceso

EJERCICIO #3

---

Realizar un pseudocódigo que permita calcular el monto total de sueldos de todos los empleados de N empleados de una empresa para el mes de Junio. Se ingresa el nombre, número de días programados y número de días que faltó por cada empleado. Además, se pide el monto total de sueldos de todos los empleados. El pago por día a cada empleado es 50 soles y el descuento por día de falta es de 100% del pago diario.

Proceso sueldos
 Definir n,dt,df Como Entero
 Definir nombre Como Caracter
 Definir aux,sTotal Como Real
 Repetir
  Escribir "Ingrese el número de empleados"
  Leer n
   sTotal <- 0
 Hasta Que n>0
 Para i<-1 Hasta n Con Paso 1 Hacer
  Escribir "Ingrese el nombre del trabajador #",i
  Leer nombre
  Repetir
   Escribir "Ingrese los días programados"
   Leer dt
  Hasta Que dt < 31 & dt > 0  
  Repetir
   Escribir "Ingrese los días que faltó"
   Leer df
  Hasta Que df <= dt & dt > 0
  aux <- (dt-df) * 50
  sTotal <- sTotal + aux
 FinPara
 Escribir "El monto total por los sueldos es: S/", sTotal
FinProceso

EJERCICIO #4

---

Desarrollar un pseudocódigo que luego de ingresar 2 números naturales, donde el segundo debe ser mayor que el primero, por teclado. Luego imprima los números naturales pares que hay entre ambos empezando por el menor y luego haga el mismo proceso para los impares

Proceso entreNumeros2
 //Variables de entrada
 Definir n1,n2 Como Entero
 //CAPTURA DE DATOS
 Repetir
  Escribir "Ingrese el primer número"
  Leer n1
 Hasta Que n1 > 0
 Repetir
  Escribir "Ingrese el segundo número"
  Leer n2
 Hasta Que n2 > n1 
 //PROCESO y SALIDA
 Si n1 % 2 <> 0 Entonces  
  Escribir "NUMEROS PARES"
  Para i<-n1+1 Hasta n2-1 Con Paso 2 Hacer
   Escribir i " ; " Sin Saltar
  FinPara  
  Escribir ""
  Escribir "NUMEROS IMPARES"
  Para i<-n1+2 Hasta n2-1 Con Paso 2 Hacer
   Escribir i " ; " Sin Saltar
  FinPara
 SiNo
  Escribir "NUMEROS PARES"
  Para i<-n1+2 Hasta n2-1 Con Paso 2 Hacer
   Escribir i " ; " Sin Saltar
  FinPara  
  Escribir ""  
  Escribir "NUMEROS IMPARES"
  Para i<-n1+1 Hasta n2-1 Con Paso 2 Hacer
   Escribir i " ; " Sin Saltar
  FinPara  
  Escribir ""
 FinSi
FinProceso

EJERCICIO #5

---

Crear una algoritmo en pseudocódigo que permita ingresar un número positivo y muestre el número de cifras totales, el número de cifras pares e impares

Proceso cifras
   //Variables de entrada
   Definir a Como Entero 
   //Variables de salida
   Definir c,cp,ci Como Entero 
   //Inicializacion de contadores
   c<-0
   cp<-0
   ci<-0
   //CAPTURA DE DATOS
   Repetir
     Escribir "Ingrese un número positivo"
     Leer a
   Hasta Que a > 0
   //PROCESO y SALIDA
   Mientras a<>0 Hacer
     Si (a % 10) % 2 = 0 Entonces
       cp<-cp+1
     SiNo
       ci<-ci+1   
     FinSi
     a<-TRUNC(a/10)
     c<-c+1
   FinMientras
   Escribir "Cifras pares  : ",cp
   Escribir "Cifras impares: ",ci
   Escribir "Cifras totales: ",c
FinProceso