Ejercicios con PseInt de estructuras condicionales - Intermedio

EJERCICIO #1

---

Construir un pseudocódigo que permita ingresar un número y devuelva un mensaje de acuerdo a la siguiente tabla:

Valor	Mensaje
Menor de 0	Negativo
Igual a 0	Neutro
Mayor de 0	Positivo

Proceso rangos
   //Variable de entrada
   Definir num Como Real  
   //CAPTURA DE DATOS
   Escribir "Ingrese el número"
   Leer num
   //PROCESO y SALIDA
   Si num < 0 Entonces
     Escribir "Negativo"
   SiNo
     Si num = 0 Entonces
       Escribir "Neutro"
     SiNo   
       Escribir "Positivo"
     FinSi
   FinSi
FinProceso

EJERCICIO #2

---

Construir un pseudocódigo que permita ingresar dos número y un símbolo (+,-,x,÷) y dependiendo del operador devuelva la suma, la diferencia, el producto o la división. Nota: verificar que el divisor no sea cero y mostrar una advertencia si se ingresa un valor diferente a esos símbolos

Proceso operadores
   //Variables de entrada
   Definir n1,n2 Como Real 
   Definir simbolo Como Caracter  
   //CAPTURA DE DATOS
   Escribir "Ingrese los números"
   Leer n1,n2
   Escribir "Ingrese el símbolo (+,-,x,÷)"
   Leer simbolo 
   //PROCESO y SALIDA
   Segun simbolo hacer
      Caso "+":
         Escribir n1 , " + ", n2, " = ", (n1+n2)
      Caso "-":
         Escribir n1 , " - ", n2, " = ", (n1-n2)
      Caso "x":
         Escribir n1 , " x ", n2, " = ", (n1*n2)
      Caso "÷":
         Si n2 <> 0 Entonces
           Escribir n1 , " ÷ ", n2, " = ", (n1/n2)
         SiNo
           Escribir "No se puede dividir entre cero"
         FinSi
      De Otro Modo:
         Escribir "ADVERTENCIA: Operador inválido"
   FinSegun
FinProceso

EJERCICIO #3

---

Realizar un pseudocódigo que permita ingresar tres números (asumimos que el usuario ingresa tres números diferentes) y nos muestre el menor de ellos.

Proceso elMenor
   //Variables de entrada
   Definir n1,n2,n3 Como Real 
   //Variable de salida
   Definir mnor Como Real 
   //CAPTURA DE DATOS
   Escribir "Ingrese tres números diferentes"
   Leer n1,n2,n3
   //Inicialización de la variable 
   //que contiene al menor
   mnor <- n1
   //PROCESO 
   Si n2 < mnor Entonces
     mnor <- n2
   FinSi 
   Si n3 < mnor Entonces
     mnor <- n3
   FinSi
   //SALIDA
   Escribir "El menor es: ", mnor
FinProceso

EJERCICIO #4

---

Construir un algoritmo que al ingresar un número desde 1 hasta el 29. Luego muestre en pantalla el número escrito en forma literal. Por ejemplo, si se ingresa 12 debe mostrar doce.

Proceso literal
   Definir num, dec, uni Como Entero
   Definir nom, unidad, decena Como Caracter
   Escribir "Ingrese un número del 1 al 29"
   Leer num
   Si num < 30 & num > 0 Entonces
     Si num < 10 Entonces
       uni <- num
       dec <- 0
     SiNo
       uni <- num % 10
       dec <- (num-uni)/10
     FinSi
     Segun dec Hacer
       0: decena <- ""
       1: 
         Segun uni Hacer
           0:
             decena <- "diez"
           1:
             decena <- "once"
           2:
             decena <- "doce"
           3:
             decena <- "trece"
           4:
             decena <- "catorce"
           5:
             decena <- "quince"
           De Otro Modo:
             decena <- "dieci"
         FinSegun    
       2: 
         Si uni <>0 Entonces
           decena <- "veinti"     
         Sino
           decena <- "veinte"
         FinSi    
     FinSegun
     Segun uni Hacer
       0:
         unidad <- ""
       1:
         unidad <- "uno"
       2:
         unidad <- "dos"
       3:
         unidad <- "tres"
       4:
         unidad <- "cuatro"
       5:
         unidad <- "cinco"
       6:
         unidad <- "seis"
       7:
         unidad <- "siete"
       8:
         unidad <- "ocho"
       9:
         unidad <- "nueve"
     FinSegun
     Si num > 9 Entonces
       Si num <=15 Entonces
         nom <- decena
       SiNo
         nom <- decena+unidad
       FinSi
     SiNo
       nom <- unidad
     FinSi
       Escribir "El número ", num, " se lee: ", Mayusculas(nom)
   SiNo
     Escribir "ADVERTENCIA: Ingrese un valor del 1 al 29"
   FinSi
FinProceso

EJERCICIO #5

---

Desarrollar un pseudocódigo que permita ingresar las medidas de los tres lados de un triángulo y mostrar en pantalla si el triángulo es equilátero, isóceles, escaleno o no puede existir.

Proceso operadores
   //Variables de entrada
   Definir l1,l2,l3 Como Real 
   //CAPTURA DE DATOS
   Escribir "Ingrese las medidas de los lados de un triángulo" 
   Leer l1,l2,l3 
   //PROCESO y SALIDA
   Si l1+l2<=l3 O l1+l3<=l2 O l3+l2<=l1 Entonces
     Escribir "El triángulo no existe"
   SiNo
     Si l1=l2 Y l2=l3 Entonces
       Escribir "El triángulo es equilátero"
     Sino
         Si l1 <> l2 Y l1 <>l3 Y l2<>l3 Entonces
           Escribir "El triángulo es escaleno"
         SiNo
           Escribir "El triángulo es isóceles"
        FinSi
     FinSi
   FinSi
FinProceso