Ejercicios con PseInt de estructuras secuenciales - Avanzado

EJERCICIO #1

---

Construir un pseudocódigo que que calcule la distancia entre dos puntos cuyas coordenadas se ingresan al algoritmo.

Proceso distancia2puntos
   //Variables de entrada
   Definir x1,y1,x2,y2 Como Real
   //Variable de salida
   Definir distancia Como Real
 
   //CAPTURA DE DATOS
   Escribir "Ingrese las coordenadas del primer punto (x1;y1)"
   Leer x1, y1
   Escribir "Ingrese las coordenadas del segundo punto (x2;y2)"
   Leer x2, y2
 
   //PROCESO
   distancia <- RAIZ( (y2-y1)^2 + (x2-x1)^2 )
 
   //SALIDA
   Escribir "La distancia entre los puntos: " Sin Saltar
   Escribir "(", x1, " ; ", y1 , ") y " Sin Saltar
   Escribir "(", x2, " ; ", y2 , ")" Sin Saltar
   Escribir " es: ", distancia
FinProceso

EJERCICIO #2

---

Construir un algoritmo que convierta un número entre 8 y 15 a binario. (No utilizar estructuras condicionales y asumir que el usuario solo ingresa valores entre 8 y 15)

Proceso binario
   //Variable de entrada
   Definir num Como Real
   //Variables auxiliares
   Definir aux Como Real
   //Variables de salida
   Definir  a,b,c Como Real
 
   //CAPTURA DE DATOS
   Escribir "Ingrese un binario entre 8 y 15"//1000 1111
   Leer num
 
   //PROCESO
   aux <- num
   a <- aux mod 2
   aux <- TRUNC(aux/2)
   b <- aux mod 2
   aux <- TRUNC(aux/2)
   c <- aux mod 2 
  
   //SALIDA
   Escribir "El número ", num," es en binario: 1",c,b,a
FinProceso

EJERCICIO #3

---

Un padre repartirá una cantidad de dinero entre sus cinco hijos. Cada uno recibirá una cantidad equivalente a:

• Tamara: 85% del monto recibido por Josué
• Josué: 27% de la cantidad a repartir
• Caleb: 23% del monto total recibido entre Josué y Daniel
• Daniel: 25% de la cantidad a repartir
• David: lo que queda del dinero a repartir

Dada la cantidad de dinero a repartir, desarrolle un pseudocodigo que determine cuánto de dinero recibirá cada hijo. (Asumimos que el usuario ingresa valores positivos en la cantidad de dinero a repartir)

Proceso reparto
   //Variable de entrada
   Definir monto Como Real
   //Variables de salida
   Definir h1,h2,h3,h4,h5 Como Real
 
   //CAPTURA DE DATOS
   Escribir "Ingrese el monto para la repartición"
   Leer monto 
 
   //PROCESO
   h2 <- monto*0.27
   h1 <- h2*0.85
   h4 <- monto*0.25
   h3 <- (h1 + h4)*0.23
   h5 <- monto-h1-h2-h3-h4
 
   //SALIDA
   Escribir "Tamara recibirá S/", h1
   Escribir "Josué recibirá  S/", h2
   Escribir "Caleb recibirá  S/", h3
   Escribir "Daniel recibirá S/", h4
   Escribir "David recibirá  S/", h5 
FinProceso

EJERCICIO #4

---

Realizar un pseudocódigo que permita ingresar el número de lados de un polígono regular y la medida de sus lados. Luego muestre el perímetro y área del polígono(Asumimos que el usuario ingresa valores positivos)

Proceso poligonos
   //Variables de entrada
   Definir lados, medida_lado Como Real
   //Variables auxiliares
   Definir angulo_interno, apotema Como Real
   //Variables de salida
   Definir perimetro, area Como Real
 
   //CAPTURA DE DATOS
   Escribir "Ingrese el número de lados"
   Leer lados
   Escribir "Ingrese la medida del lado"
   Leer medida_lado
 
   //PROCESO
   perimetro <- lados * medida_lado
   angulo_interno <- 180 - 360 / lados
   apotema <- medida_lado * TAN(angulo_interno*PI/360) / 2
   area <- perimetro * apotema / 2
   //SALIDA
   Escribir "El polígono de ", lados, " lados tiene:"
   Escribir "-> Perímetro: ", perimetro, " metros"
   Escribir "-> Área: ", area, " metros cuadrados"
FinProceso

EJERCICIO #5

---

Desarrollar un pseudocódigo que permita ingresar una oración, luego devuelva el texto en minúsculas, mayúsculas y la primera letra en mayúsculas y las demás en minúsculas.

Proceso textos
   //Variable de entrada
   Definir oracion Como Caracter
   //Variables auxiliares
   Definir long Como Entero
   Definir parte_a,parte_b Como Caracter
   //Variables de salida
   Definir minus, mayus, capital Como Caracter
 
   //CAPTURA DE DATOS
   Escribir "Ingrese una oración"
   Leer oracion
 
   //PROCESO
   minus <- MINUSCULAS(oracion)
   mayus <- MAYUSCULAS(oracion)
   long <- LONGITUD(oracion)
   parte_a <- MAYUSCULAS(SUBCADENA(oracion,1,1))
   parte_b <- MINUSCULAS(SUBCADENA(oracion,2,long))
   capital <- CONCATENAR(parte_a,parte_B)
 
   //SALIDA
   Escribir "La oración en minúscula    : ", minus
   Escribir "La oración en mayúscula    : ", mayus
   Escribir "La oración en letra capital: ", capital
FinProceso