Ejercicio con PseInt usando funciones

Las funciones dentro de PseInt se pueden crear mediante la palabra reservada SubProceso, SubAlgortimo o Función. Esto dependerá del estilo de lenguaje empleado

Enunciado:

Diseñar un algoritmo que permita determinar el pago que debe realizar un cliente en un almacén que ofrece los siguientes descuentos:

• Los productos relacionados en la línea de electrodomésticos tienen descuento del 15% si cancelas con tarjeta CMR, y 10% si pagas con otro tipo de tarjeta, 0% al cancelar en efectivo.
• Los productos de tecnología tienen descuento del 30% si cancelas con tarjeta CMR, el 20% si pagas con otro tipo de tarjeta y 10% al cancelar en efectivo.
• Los productos de hogar tienen descuento del 50% si cancelas con tarjeta CMR, el 30% si pagas con otro tipo de tarjeta y 30% al cancelar en efectivo.

Se debe realizar una función que dado el tipo de producto (electrodoméstico, tecnología, u hogar), y el modo de pago, retorne el porcentaje del descuento a aplicar. El descuento final se calculará en el programa principal del algoritmo.

Proceso avenidas
	Definir monto Como Real
	Definir av1, av2,av3,av4,av5 Como Real

	Escribir "Ingrese el monto para la reparación"
	Leer monto

	av1 <- monto*0.35 
	av2 <- monto*0.25 
	av3 <- monto*0.10 
	av4 <- monto*0.15
	av5 <- monto-av1-av2-av3-av4

	Escribir "La avenida La mar recibirá S/", av1
	Escribir "La avenida Abancay recibirá S/", av2
	Escribir "La avenida 28 de Julio recibirá S/", av3 
	Escribir "La avenida Aviación recibirá S/", av4 
	Escribir "La avenida Tacna recibirá S/", av5
FinProceso

Solución planteada

Proceso pagos
	Definir tipo, metodo Como Entero
	Definir monto,dscto Como Real
	
	Hacer
		Escribir "Ingrese el tipo de producto"
		Escribir "1 - Electrodomésticos"
		Escribir "2 - Tecnología"
		Escribir "3 - Hogar"	
		Leer tipo	
	Mientras Que (tipo < 1 O tipo > 3)
	
	Hacer
		Escribir "Ingrese el método de pago"
		Escribir "1 - CMR"
		Escribir "2 - Otro tipo de tarjeta"
		Escribir "3 - Efectivo"
		Leer metodo
	Mientras Que (metodo < 1 O metodo > 3)
	
	Hacer
		Escribir "Ingrese el monto del producto"
		Leer monto
	Mientras Que (monto < 0)
	
	dscto <- descuento(tipo,metodo)
	Escribir "Descuento: ",dscto,"%"
	Escribir "==========================="
	Escribir "Importe    : S/",monto
	Escribir "Descuento  : S/",monto*dscto/100
	Escribir "Pago final : S/",monto*(1-dscto/100)
	
FinProceso

SubProceso valor <- descuento  (tipo, metodo)
	Segun tipo Hacer
		1:
			Segun metodo Hacer
				1: valor <- 15
				2: valor <- 10
				3: valor <- 0	
			FinSegun
		2:
			Segun metodo Hacer
				1: valor <- 30
				2: valor <- 20
				3: valor <- 10	
			FinSegun
		3:	
			Segun metodo Hacer
				1: valor <- 50
				2: valor <- 30
				3: valor <- 30	
			FinSegun
	FinSegun
FinSubProceso